Newtonin jäähtymislaki

1600- ja 1700-lukujen vaihteessa elänyt fyysikko ja matemaatikko Isaac Newton tutki kappaleiden jäähtymistä vakiolämpöisessä ympäristössä. Kokeidensa tuloksena hän esitti ns. Newtonin jäähtymislain

((d T (t))/(d t)) = -k (T (t) - 
              (Subscript[T, 0])).

Tässä T (t) ilmaisee tarkasteltavan kappaleen lämpötilan hetkellä t, (Subscript[T, 0]) on ympäristön lämpötila ja k jäähtymisvakio. Käyttäen tätä yksinkertaista jäähtymislakia ratkaisemme seuraavan jäähtymisongelman.

Kuparipallo, jonka lämpötila on 100°C, upotetaan veteen, jonka lämpötilaa ylläpidetään 30°C:ssa. Upotus tapahtuu ajanhetkellä t = 0, ja kolmen minuutin päästä pallon lämpötila on pudonnut 70°C:seen. Kauanko kestää ennen kuin pallon lämpötila on alle 31°C?

Laskujen aluksi on syytä hävittää mahdollisista aiemmista laskuista jääneet muuttujat.

Remove["Global`*"]

Muodostetaan Newtonin jäähtymislain mukainen differentiaaliyhtälö:

yht =  T'[t]  ==  -k (T[t] - T0)

Probleeman tuntematon funktio on lämpötila T (t).

tuntematon =  T[t]

Alkuehtona on kuparipallon lämpötila on 100°C upotuksen tapahtuessa:

alkuehto = T[0] == 100

Ratkaistaan differentiaaliyhtälöryhmä ja manipuloidaan tulos käyttökelpoiseen muotoon.

rtk =  DSolve[{yht, alkuehto}, tuntematon, t]

lampo = tuntematon /. First[rtk] // FullSimplify

Asetetaan vakio (Subscript[T, 0]).

T0 = 30

Ratkaistaan k sijoittamalla t = 180  s, jolloin kuulan läpötilan tulee olla 70°C.

krtk = Solve[(lampo /. t -> 180) == 70, k]

Mathematica varoittaa, että Solve mahdollisesti ei löydä kaikkia yhtälön ratkaisuja. Tässä tapauksessa ongelmia ei kuitenkaan ole. Seuraavaksi ratkaistaan, millä arvolla t lämpötila on 31°C.

tulos = 
      N[Solve[(lampo /. First[krtk]) == 31, t]]

Tämä on lähes 23 minuuttia (1380 s). Jälleen varoitus mahdollisesti löytämättä jäävistä juurista.

Piirretään vielä lopuksi kuvaaja lämpötilan kehityksestä ajan funktiona.

Plot[lampo /. krtk, {t, 0. , 1400}, 
      PlotStyle -> Hue[ .7]]

On syytä huomata, että Newtonin tekemä malli on hyvin rajoitettu. Sitä käytettäessä ei kiinnitetä minkäänlaista huomiota siihen, että massiivisen kuulan ollessa kysymyksessä kuulan pinta jäähtyy sisäosaa nopeammin. Samaten kuulan ympärillä olevalle vedelle täytyy järjestää tasainen ja hyvä sekoittuminen, joka varmistaa sen tasalämpöisyyden. Kuitenkin pienille ja hyvin lämpöä johtaville kappaleille Newtonin malli on hyvä approksimaatio.

Tehtävä

Sama kuparipallo otetaan vedestä ja jäähdytetään 0°C:een. Laske Newtonin mallia käyttäen kauanko kestää, että kuparipallo lämpenee 29°C lämpötilaan, kun se jälleen upotetaan veteen.

JP & SKK 03.05.2001