Laskuvarjohyppy

Heittoliikkeeseen kuuluu keskeisinä tekijöinä maan vetovoima sekä ilmanvastuksen aiheuttama nopeudelle vastakkaissuuntainen voima. Näitä voimia sovelletaan myös mallinnettaessa  laskuvarjolla hyppäämistä.

Tarkastellaan ensin vapaata putoamista. Putoajaan vaikuttava voima aiheuttaa kiihtyvyyden, joka saa aikaan nopeuden. Yleisessä muodossa voimalle pätee

\(\(\(F\&_ = m\ a\&_\)\(,\)\)\)

missä m on tarkasteltavan kohteen massa ja \(a\&_\) kiihtyvyys. Hyppääjään vaikuttavat voimat ovat painovoima  \(G\&_ = m\ g\&_\), missä \(g\&_\) on maan vetovoiman aiheuttama kiihtyvyys, sekä ilmanvastusvoima, jota arvioidaan lausekkeella

\(F\&_ = \(\(-b\)\ \(v\^2\) 
          v\&^\  = \ \(-b\)\ v\ \(\(v\&_\)\(.\)\)\)\)

Tässä b on ilmanvastuskerroin, v skalaarinen nopeus, \(v\&_\) nopeus vektorina ja \(v\&^\) nopeuden suuntainen yksikkövektori. Liikeyhtälö saa tällöin muodon

\(\(\(m \(\( d\^2\) r\&_\)\/\(d\ t\^2\) = 
      m  g\&_\  - 
          b\  | \(d\ r\&_\)\/\(d\ t\) | \ \(d\ r\&_\)\/\(d\ t\)\)\(\ \)\(,\)\)\)

missä on merkitty \(a\&_\)=\(\(\(d\^2\) r\&_\)\/\(d\ t\^2\)\) ja \(v\&_\)=\(\(d  r\&_\)\/\(d\ t\)\).

Tämä on heittoliikkeen differentiaaliyhtälö yleisessä muodossa.

Tehdään tarvittavat laskut laskuvarjohyppääjän lentoradan ja -nopeuden selvittämiseksi. Edellä esitetty ilmanvastusmalli on vain approksimaatio todelliselle ilmanvastukselle. On myös huomattava, että mikäli hyppääjä putoaa ilman varjoa, ilmanvastustekijä on aivan eri suuruinen kuin varjon kanssa.

Laskujen aluksi on syytä hävittää mahdollisista aiemmista laskuista jääneet muuttujat.

Remove["Global`*"]

Määritellään differentiaaliyhtälö normaaliryhmänä, jossa on erikseen x ja y-komponentit.

ryhma =  {x'[t]  ==  
          u[t],   m u'[t] == - b Sqrt[
              u[t]^2  +  v[t]^2] u[t], y'[t]  ==  v[t], 
        m v'[t]  == -m g  -  
            b Sqrt[u[t]^2  +  v[t]^2] v[t]}

Probleeman tuntemattomat funktiot ovat vaakasijaintia kuvaava x(t) sekä korkeus y(t) ja vastaavat nopeudet u(t) ja v(t).

tuntemattomat =  {x[t], y[t], u[t], v[t]}

Määritetään parametrit ja valitaan alkuehdot lentokoneesta hypättäessä. Oletetaan, että kyseessä on hitaasti lentävä koulutuslentokone.

m = 70; b = 30; g = 9.81;

alkuehto = {x[0] == 0, y[0] == 1000, u[0] == 20, 
        v[0] == 0}

Ratkaistaan differentiaaliyhtälöryhmä.

rtk =  
      NDSolve[Flatten[{ryhma, alkuehto}], 
        tuntemattomat, {t, 0, 250}]

Muokataan tulos käyttökelpoiseen muotoon.

rata =  
      tuntemattomat[[{1, 2}]] /. First[rtk]

nopeus =  
      tuntemattomat[[{3, 4}]] /. First[rtk]

Piirretään kuva laskuvarjohyppääjän lentoradasta. Huomaa koordinaattiakselien eri skaalat!

ParametricPlot[rata, {t, 0, 250}, PlotStyle -> Hue[ .3], 
      PlotRange -> {{0, 10}, {950, 1000}}]

FindRoot[rata[[2]] == 0, {t, 200}]

Lentorata ei muodostunut kovin pitkäksi ja laskeutuminen kilometrin korkeudelta tapahtui n. 3.5 minuutissa. Tarkastellaan vielä hyppääjän nopeutta.

Plot[Evaluate[nopeus], {t, 0, 250}, 
      PlotStyle -> {Hue[0.3], Hue[0.6]}, 
      PlotRange -> {{0, 5}, {-6, 20}}]

nopeus /. Table[{t -> k}, {k, 1, 10}] // 
      TableForm

Vaakasuuntainen nopeus lähes häviää ja putoamisnopeus asettuu vajaaseen 4.8 m/s nopeuteen jo kahden ensimmäisen sekunnin aikana. Hyppääjän putoamisvauhti maahan on siis noin 17 km/h, joka on suurenpuoleinen jaloilla vastaanotettavaksi.

Tarkastellaan seuraavaksi tilannetta, jossa hyppääjä ei avaa varjoaan välittömästi. Tehdään vastaava tarkastelu kuin edellä, paitsi että ilmanvastuskerroin b muuttuu hyppääjän avatessa varjon. Oletetaan, että ilman varjoa hyppäävän ihmisen maksiminopeus (vaikuttavien voimien summa on 0) eli ns. terminaalinopeus on runsaat 200 km/h eli n. 60 m/s. Tällöin ilmanvastuskerroin voidaan ratkaista yhtälöstä F  =  m g  -  b (v^2)  =  0, jolloin b  =  m g / (v^2).

b0 = 70*9.81/60^2

Jotta ilmanvastuskertoimen arvo (Subscript[b, 0]) = 0.19075 voidaan varjon auetessa muuttaa arvoon b = 30, tarvitaan funktio, joka mallintaa muutoksen. Tällaiseksi sopii

f[x_] := 1 - Exp[- Exp[2  x - 0.5]]

jonka kuvaaja näyttää seuraavalta:

Plot[f[x], {x, -10, 10}, PlotRange -> {-0.5, 1.5}, 
      PlotStyle -> Hue[ .3]]

Määritetään putoamisyhtälöt uudestaan. Ilmanvastuskerroin määräytyy nyt funktiosta

bb[t_] := b0 + (b - b0) f[t]

ja uusi yhtälöryhmä on

ryhma2 =  {x'[t]  ==  
          u[t],   m u'[t] == - bb[t  -  20] Sqrt[
              u[t]^2  +  v[t]^2] u[t], y'[t]  ==  v[t], 
        m v'[t]  == -m g  -  
            bb[t  -  20] Sqrt[u[t]^2  +  v[t]^2] v[
                t]}

Varjon on oletettu aukeavan 20 sekuntia hyppäämishetken jälkeen.

Ratkaistaan yhtälöryhmä.

rtk2 =  
      NDSolve[Flatten[{ryhma2, alkuehto}], 
        tuntemattomat, {t, 0, 50}]

rata2 =  
      tuntemattomat[[{1, 2}]] /. First[rtk2]

nopeus2 =  
      tuntemattomat[[{3, 4}]] /. First[rtk2]

Piirretään kuvaaja hyppääjän lentoradasta, määritetään alastulohetki ja alastulonopeus:

ParametricPlot[rata2, {t, 0, 50}, PlotStyle -> Hue[ .3], 
      PlotRange -> {{0, 200}, {0, 1000}}]

alas =  FindRoot[rata2[[2]] == 0, {t, 50}]

nopeus2 /. alas

Tarkastellaan vielä putoamisnopeuksia kokonaistilanteen hahmottamiseksi. Putoamisnopeudet ajan funktiona ovat

Plot[Evaluate[nopeus2], {t, 0, 50}, 
      PlotStyle -> {Hue[0.3], Hue[0.6]}, 
      PlotRange -> {{0, 50}, {-60, 20}}, 
      GridLines -> {{17, 20}, {}}]

rata2 /. t -> 17

Putoaminen tapahtuu varsin eri tavalla kuin avoimella varjolla. Vaikka varjon avautumishetkeksi asetettiin 20 s, avautuminen on alkanut askefunktion mukaisesti muuttamaan ilmanvastuskerrointa radikaalisti ja siten jarruttamaan putoamista jo aikaisemmin. Nopeus alkaa vähetä noin 250 metrin korkeudessa, kun  t = 17 s.

Kiihtyvyys:

Plot[Evaluate[D[nopeus2[[2]], t]], {t, 0, 50}, 
      PlotRange -> All, PlotStyle -> Hue[0.6], 
      GridLines -> {{19}, {}}]

D[nopeus2[[2]], t] /. t -> 19

Voimakkain jarrutuskiihtyvyys (n. 28(m/(s^2))) tapahtuu kohdassa  t=19 s. Putoamisen kokonaisajasta avatun varjon kanssa kuluu yhä yli puolet, vaikka matka on noin  viidennes.

Tehtävä

Milloin hyppääjän on viimeistään vedettävä varjon avausnarusta, kun oletetaan, että tämän on tapahduttava 3 sekuntia ennen askelfunktiossa käytettyä aikaa? Suurin mahdollinen nopeus maahan pudotessa ilman loukkaantumista on 10 m/s. Mikä on tällöin putoamisen kokonaisaika?

JP & SKK 03.05.2001