Wronskin determinantin differentiaaliyhtälön johtaminen

Wronskin determinantti määritellään homogeenisen lineaariyhtälön ratkaisujen ja niiden derivaattojen muodostamana determinanttina, mutta sille voidaan johtaa yksinkertainen differentiaaliyhtälö, joka näyttää, miten determinantti riippuu vain yhdestä differentiaaliyhtälössä olevasta kerroinfunktiosta. Johto on seuraavassa toteutettuna Mathematican keinoin. Lukija miettiköön, millainen tehtävä olisi käsin ratkaistuna (kuten toisen kertaluvun osalta on differentiaaliyhtälöiden kursseissa perinteisesti tehty).

Syötetään aluksi kertaluku ja muodostetaan vastaava normaalimuotoinen homogeeninen differentiaaliyhtälö, jossa kerroinfunktioita merkitään (Subscript[P, 0]), (Subscript[P, 1]) jne. Differentiaaliyhtälössä korkeimman kertaluvun termi annetaan erikseen, muut voidaan antaa summalausekkeena.

n = 3

diffyht =  
      D[y[x], {x, n}]  +  
          Sum[(Subscript[P, k])[x] D[y[x], {x, k}], {k, 0, n - 1}]  ==  
        0

Olkoot (Subscript[y, 1]), (Subscript[y, 2]), ..., (Subscript[y, n]) differentiaaliyhtälön ratkaisuja. Sijoitetaan nämä yhtälöön, jolloin saadaan seuraavat yhtälöt:

diffyhtsij =  
      Table[diffyht /. y -> (Subscript[y, k]), {k, 1, n}]

Nämä ovat voimassa kaikilla arvoilla x.

Kerätään ratkaisut listaksi ja tätä derivoimalla muodostetaan vastaavat derivaattojen muodostamat listat. Kun nämä kerätään matriisiksi, saadaan Wronskin determinanttia vastaava matriisi.

ratk =  Table[(Subscript[y, k])[x], {k, 1, n}]

wronskimatr =  
      Table[D[ratk, {x, k}], {k, 0, n - 1}]

Matriisi on Mathematicassa listojen lista, mutta se voidaan tulostaa myös havainnollisemmassa muodossa:

wronskimatr // MatrixForm

Wronskin determinantti on saadun matriisin determinantti. Tämä kehitetään ja sijoitetaan oikeaksi puoleksi yhtälöön, jonka vasempana puolena on Wronskin determinantin symboli (jolle differentiaaliyhtälöä haetaan):

wronskidet =  w[x]  ==  Det[wronskimatr]

Derivoimalla saadaan vastaava Wronskin determinantin derivaattaa koskeva yhtälö:

wronskidetder =  D[wronskidet, x]

Wronskin determinantti ja sen derivaatta on saatu lausutuiksi ratkaisujen ja niiden derivaattojen avulla. Toisaalta ratkaisut toteuttavat alkuperäisen differentiaaliyhtälön. Jos näistä yhtälöistä voidaan eliminoida ratkaisufunktiot derivaattoineen, saadaan ehto, joka sitoo Wronskin determinantin, sen derivaatan ja differentiaaliyhtälön kerroinfunktiot. Ennalta ei ole selvää, että tällainen yhteys on olemassa.

Ehtoyhtälöitä on n  + 2 kappaletta:

yhtalot =  
      Flatten[{diffyhtsij, wronskidet, wronskidetder}]

Eliminoitavia symboleja ovat ratkaisut ja näiden derivaatat; yhteensä n(n + 1) kappaletta:

eliminoitavat =  
      Flatten[Table[D[ratk, {x, k}], {k, 0, n}]]

Eliminointi onnistuu, ja sen tuloksena saadaan ensimmäisen kertaluvun differentiaaliyhtälö Wronskin determinantille:

wronskidiffyht =  
      Eliminate[yhtalot, eliminoitavat]

Differentiaaliyhtälö voidaan ratkaista:

DSolve[wronskidiffyht, w[x], x]

Huomaa, että Wronskin determinantti riippuu vain toiseksi korkeinta kertalukua olevan derivaatan kerroinfunktiosta. Integroimismuuttuja on Mathematican sisäisesti käyttöön ottama, ja sillä on tämän johdosta käyttäjän muuttujista varmasti eroava nimi.

Lukija voi muuttaa alussa annettua differentiaaliyhtälön kertalukua ja tutkia, miten Wronskin determinantin differentiaaliyhtälön etsiminen tällöin sujuu.

SKK 27.04.2001