Käyräparven kohtisuorat leikkaajat napakoordinaattitapauksessa

Esimerkki on jatkoa 'Käyräparven kohtisuorat leikkaajat' -esimerkille, jossa vastaavaa ongelmaa on tarkasteltu suorakulmaisissa koordinaateissa.

Puhdistetaan työtila:

Remove["Global`*"]

Käyräparvi voidaan antaa myös napakoordinaattiesityksenä muodossa r  =  (Subscript[r, 1])(φ). Olkoon annettuna myös toinen käyräparvi r  =  (Subscript[r, 2])(φ). Ehto näiden kohtisuoralle leikkaamiselle voidaan johtaa seuraavasti:

Kummankin käyrän pisteiden suorakulmaiset koordinaatit saadaan vektoreista

v1 =  {(Subscript[r, 1])[φ] Cos[φ], 
        (Subscript[r, 1])[φ] Sin[φ]}

v2 =  {(Subscript[r, 2])[φ] Cos[φ], 
        (Subscript[r, 2])[φ] Sin[φ]}

Näissä napakulma φ on käyräparametrin asemassa. Käyrien tangenttivektorit saadaan derivoimalla käyräparametrin suhteen:

t1 =  D[v1, φ]

t2 =  D[v2, φ]

Käyrien leikkaamisen kohtisuoruusehto on, että tangenttivektorit ovat toisiaan vastaan kohtisuorat, ts. niiden pistetulo on = 0:

kohtisuoruusehto =  t1 . t2  ==  0 // Simplify

Ratkaisemalla tästä \(TraditionalForm\`\(r\_1\%'\)(φ)\) ja ottamalla huomioon, että leikkauspisteessä on \(TraditionalForm\`\(r\_1\)(φ)\  = \ \(\(r\_2\)(φ)\  = \ r(φ)\)\), saadaan

Solve[kohtisuoruusehto,(Subscript[r, 1]^′)[φ]]/.{(Subscript[r, 1])[φ] ->  r[φ], 
        (Subscript[r, 2])[φ] ->  r[φ]}

Korvausehto, joka tarvitaan johdettaessa alkuperäisen parven differentiaaliyhtälöstä kohtisuorien leikkajien differentiaaliyhtälö, on siis

r'(φ) ↦ -(((r(φ))^2)/(r'(φ))) .

Esimerkkinä olkoon käyräparven

parvi =  
      r[φ] == C Exp[k φ]

kohtisuorien leikkaajien etsiminen.

Käyräparven kuva arvolla k  =  (1/2) voidaan piirtää Mathematican lisäpaketissa Graphics`Graphics` olevaa funktiota PolarPlot käyttäen:

<< Graphics`Graphics`;
kuva1 =  
      PolarPlot[
        Evaluate[
          Table[parvi[[2]] /. k -> 0.5, {C, 1, 
              10}]], {φ, -2, 6}]

Käyräparven differentiaaliyhtälön johto:

derivparvi =  D[parvi, φ]

diffyht =  Eliminate[{parvi, derivparvi}, C]

Kohtisuorien leikkaajien differentiaaliyhtälö saadaan tekemällä alussa johdettu korvaus:

diffyht2= diffyht/.r'[φ]->-((r[φ]^2)/(r'[φ]))

Tämän ratkaiseminen antaa kohtisuorat leikkaajat:

ratk =  
      DSolve[diffyht2, r[φ], φ]

parvi2 =  
      r[φ]  ==  (r[φ] /. Last[ratk] /. 
            C[1] -> C)

Kuva kohtisuorien leikkaajien parvesta arvolla k  =  (1/2) ja molemmista parvista yhdessä:

kuva2 =  
      PolarPlot[
        Evaluate[
          Table[parvi2[[2]] /. k -> 0.5, {C, 1, 
              20}]], {φ, -6, 2}, 
        PlotRange -> {{-75, 75}, {-120, 30}}, 
        AspectRatio -> Automatic]

Show[kuva1, kuva2, 
      PlotRange -> {{-75, 75}, {-120, 30}}, 
      AspectRatio -> Automatic]

Kuvasta voidaan ottaa osasuurennus:

Show[kuva1, kuva2, PlotRange -> {{0, 10}, {-5, 5}}, 
      AspectRatio -> Automatic]

Tehtäviä

Etsi napakoordinaateissa annetun käyräparven r  =  C cos φ kohtisuorat leikkaajat. Mieti ennen piirtämistä, millaisesta käyräparvesta on kyse.

Tutki, millainen korvausehto saadaan, jos käyräparvien halutaan leikkaavan 45 asteen kulmassa. Sovella tätä
sekä esimerkin alkuperäiseen käyräparveen että edellisen tehtävän parveen.

SKK 10.05.2001