Radioaktiivinen hajoaminen

Radioaktiivinen hajoaminen on ilmiö, jossa aktivoitunut, epästabiili atomiydin vapauttaa energiaansa α-, β- tai γ-säteilyn kautta. Hiukkassäteilyn eli α- ja β-säteilyn tapauksessa samalla muuttuu myös atomiytimen sisäinen kokoonpano. Tällaisen hajoamisen kautta alkuaine muuttuu toiseksi.

Erityisen paljon tutkittuja ovat ydinreaktorien polttoainesauvoihin jäävien radiokatiivisten aineiden hajoamisketjut. Polttoainesauvoista muodostuva pitkään radioaktiivinen jäte aiheuttaa huolestumista, koska sauvoissa olevien radioaktiivisten aineiden hajoaminen on niin hidasta, että säteilyongelma säilyy luonnollisen hajoamisen kautta akuuttina vuosituhansia. Tämä esimerkki käsittelee radiumin (Ra^228) hajoamista sekä yksinkertaistettua radiumin (Ra^224) ytimen hajoamisketjua lyijyksi (Pb^208). Tämä ketju muodostaa loppuosan varsin tärkeästä toriumin (Th^232) hajoamisketjusta.

Jokaiselle radioaktiiviselle atomiytimelle on olemassa tietty todennäköisyys sen hajoamiseen määrätyllä aikavälillä. Hajoamisen kautta syntyvien tytäratomien lukumäärä on siten suoraan verrannollinen aktiivisten atomiytimien lukumäärään. Niinpä voidaan määrittää radioaktiivinen hajoamislaki

((dN)/(dt))=-λN,

missä N on radioaktiivisten ytimien lukumäärä, t on aika ja λ radioaktiivinen hajoamisvakio, joka määrittää todennäköisyyden atomiytimen spontaanille hajoamiselle annetulla ajanhetkellä. Hajoamislain perusteella voidaan määrittää ns. puoliintumisaika (Subscript[T, 1/2]), joka ilmoittaa sen aikayksikön, jossa puolet alkuperäisistä ytimistä on hajonnut. Integroimalla saadaan hajoamattomien ytimien lukumäärälle

N=(Subscript[N, 0]) (e^(-λt)),

jossa (Subscript[N, 0]) on ydinten lukumäärä ajanhetkellä t = 0. Ratkaisemalla yhtälö N = (1/2) (Subscript[N, 0])saadaan puoliintumisajalle (Subscript[T, 1/2]) = (ln2/λ). Tällöin hajoamislaille pätee

((dN)/(dt))=-((ln 2)/((Subscript[T, 1/2])))N.

Yksinkertainen hajoamistilanne

Radium (Ra^228) on yksi väliydin pitkäaktiivisen (Th^232):n hajoamisketjussa. (Ra^228):n puoliintumisaika on 5,75 vuotta sen hajotessa lyhytaktiiviseksi (Ac^228)-ytimeksi. Lasketaan kuinka paljon 100 kg:sta  (Ra^228):sta on jäljellä 70 vuoden kuluttua.

Laskujen aluksi on syytä hävittää mahdollisista aiemmista laskuista jääneet muuttujat.

Remove["Global`*"]

Ytimien hajoamista kuvaava differentiaaliyhtälö.

yht = n'[t] == -λ n[t]

Alkuehdon määrittää tilanne, jossa on vain  (Ra^228) ytimiä. Lasketaan ainemäärä kilogrammoissa.

alkuehto = n[0] == 100

Ratkaistaan differentiaaliyhtälö.

rtk =  DSolve[{yht, alkuehto}, n[t], t]

Sievennetään tulos ja sijoitetaan siihen hajoamisvakio. Käytetään aikayksikkönä vuosia.

ainemaara =  n[t] /. First[rtk] /. λ -> 
          Log[2]/5.75

Piirretään kuvaaja ainemäärän kehitykselle ajan fuktiona 50 vuoden aikajaksolla.

Plot[ainemaara, {t, 0, 50}, 
      PlotStyle -> Hue[ .3]]

70 vuoden jälkeen jäljelle jääneen ainemäärän paino kilogrammoissa selviää sijoittamalla ajaksi 70 vuotta.

jaljella = ainemaara /. t -> 70

Tuloksena on siis 21,6 grammaa Radium (Ra^228):aa.

Hajoamisketju

Myös Radium (Ra^224) on väliydin (Th^232):n hajoamisketjussa. Hajoamisketju (Ra^224) ytimestä eteenpäin sisältää useita lyhytaikaisia ja muutamia pitkäaikaisia väliytimiä ennen hajoamista pysyväksi lyijy-ytimeksi (Pb^208). Tarkastelemme nyt hajoamista väliytimet (Pb^212) ja (Bi^212) huomioiden. Puoliintumisajat ytimien hajoamisille ovat seuraavat:

(Ra^224)->(Pb^212) : (Subscript[T, 1/2, (Ra^224)])=3.6 päivää
(Pb^212)->(Bi^212) : (Subscript[T, 1/2, (Pb^212)])=10.6 tuntia
(Bi^212)->(Pb^208) :  (Subscript[T, 1/2, (Bi^212)])=61 minuuttia

Muodostetaan hajoamisketjua kuvaavat differentiaaliyhtälöt:

(Subscript[N, 1])'=-(Subscript[λ, 1])(Subscript[N, 1])
(Subscript[N, 2])' = (Subscript[λ, 1]) 
                  (Subscript[N, 1]) - (Subscript[λ, 2]) (Subscript[N, 2])
(Subscript[N, 3])' = (Subscript[λ, 2]) 
                  (Subscript[N, 2]) - (Subscript[λ, 3]) (Subscript[N, 3])
(Subscript[N, 4])' = (Subscript[λ, 3]) 
                (Subscript[N, 3])

jossa (Subscript[N, 1]) on (Ra^224)-atomien lukumäärä ja (Subscript[λ, 1]) vastaavasti (Ra^224):n hajoamisvakio. Vastaavasti alaindeksi '2' viittaa (Pb^212):n, '3'  (Bi^212):n ja '4' (Pb^208):n vastaaviin suureisiin. Ratkaistaan hajoamisketjun differentiaaliyhtälöryhmä ja piirretään kuvaajat ytimien lukumäärille ajan funktioina.

Ytimien hajoamisia ja toisikseen muuttumista kuvaa seuraava normaaliryhmä.

ryhma1 =  {n1'[t]  ==  -λ1*
            n1[t],   n2'[
            t]  ==  λ1*n1[t] - λ2*n2[t],  n3'[
            t]  ==  λ2*n2[t] - λ3*
              n3[t],   n4'[t]  ==  λ3*
            n3[t]}

Ongelman tuntemattomat funktiot ovat ketjun eri alkuaineiden ydinten lukumäärät.

tuntemattomat1 =  {n1[t], n2[t], n3[t], n4[t]}

Alkuehdon määrittää tilanne, jossa on (10^16) kpl (Ra^224) ytimiä (n. 3,72×(10^(-6)) g):

alkuehto1 = {n1[0] == 10^16, n2[0] == 0, n3[0] == 0, 
        n4[0] == 0}

Hajoamisvakiot ovat

λ1 = Log[2]/
        3.6 
 λ2 = Log[2]/(10.6/24)
 λ3 = Log[2]/(61. /60/24)

Ratkaistaan differentiaaliyhtälöryhmä ja sievennetään tulokset:

rtk1 =  
      DSolve[Flatten[{ryhma1, alkuehto1}], tuntemattomat1, 
        t]

maarat1 =  
        tuntemattomat1 /. First[rtk1] // 
          Simplify;
maarat1 // TableForm

Piirretään kuva ainemäärien muuttumisesta ajan funktiona. Tarkasteltavana aikavälinä käytetään yhtä kuukautta.

<< Graphics`Graphics`

DisplayTogether[
      Plot[maarat1[[1]], {t, 0, 30}, PlotStyle -> Hue[ .3]], 
      Plot[maarat1[[2]], {t, 0, 30}, PlotStyle -> Hue[ .5]], 
      Plot[maarat1[[3]], {t, 0, 30}, PlotStyle -> Hue[ .7]], 
      Plot[maarat1[[4]], {t, 0, 30}, PlotStyle -> Hue[ .9]], 
      PlotRange -> {0, 10^16}]

Lähtöytimien (Ra^224) (vihreä) hajoamisessa syntyy ensin turkoosilla merkittyjä (Pb^212) ytimiä jotka nopeasti hajoavat violetilla merkityiksi (Bi^212) ytimiksi. Niiden puoliintumisaika on kuitenkin niin lyhyt, että ne hajoavat hyvin nopeasti (Pb^208) ytimiksi. Jo viidentoista päivän kuluttua lähtöhetkestä on jäljellä lähinnä vain vakaita punaisella piirrettyjä (Pb^208) ytimiä. Eniten niiden syntymistä hidastaa lähtöytimien verrattain lyhyt puoliintumisaika.

Tehtävä

Testaa puoliintumisajan vaikutusta radioaktiivisessa hajoamisessa. Mikäli puolitat (Ra^228):n puoliintumisajan, kuinka paljon vähemmän ytimiä on jäljellä 4 puoliintumisajan jälkeen verrattuna todelliseen tilanteeseen?

Mikäli haluat tutustua tarkemmin radioaktiivisiin hajoamisketjuihin, voit tutustua niihin Internetissä Uranium Information Centren kotisivuilla Australiassa. Loistava laskuri hajoamisketjujen simuloimiseksi löytyy Project Javan kotisivuilta, missä yksi ohjelmointikilpailutyö keskittyy hajoamisketjujen laskemiseen.

JP & SKK 04.05.2001