RLC-vaihtovirtapiiri: resonanssi

Olkoon tarkastelun kohteena tavallinen RLC-vaihtovirtapiiri. Piirissä on kolme komponenttia, R ohmin vastus, L henryn induktanssi ja C faradin kapasitanssi.

Piiriin syötettyyn jännitteeseen kohdistuu kolme eri pudotusta,

(Subscript[E, L])=L ((d I(t))/(d t))                        käämin yli, 
(Subscript[E, R])=R I(t)                                  vastuksen yli   sekä
(Subscript[E, C])=(1/C)∫I(t)\[DifferentialD]t                kondensaattorin yli.

Näiden summasta syntyy piirin Kirchhoffin lain mukainen sähkömotorinen voima E(t). Mikäli piiriin syötetty jännite on sinimuotoista vaihtovirtaa E(t)  =  (Subscript[E, 0]) sin(ω t), saadaan piirille yhtälö

E(t)=L ((d I(t))/(d t))+R I(t)+(1/C)∫I(t)\[DifferentialD]t=(Subscript[E, 0])sin(ω t).

Integraalitermistä päästään eroon derivoimalla yhtälö ajan suhteen:

L (((d^2)I(t))/(d (t^2)))+R ((d I(t))/(d t))+(1/C)I(t)=(Subscript[E, 0])ω cos(ω t).

Tämä on differentiaaliyhtälö pakotetulle värähtelylle, jossa ulkoinen pakottava jännite on sinimuotoinen amplitudina (Subscript[E, 0]).

Jos E(t)=0, kyseessä vapaa värähtelypiiri ja  differentiaaliyhtälö on homogeeninen.

Jos piirissä ei ole vastusta, ts. R  =  0, piiri on vaimentamaton. Vastuksen olemassaolo merkitsee, että piirissä on vaimennnus.

Tarkastellaan differentialiyhtälön ratkaisuja vakioiden L, R, C, (Subscript[E, 0]) ja ω eri arvoilla.

Aluksi hävitetään mahdollisista aiemmista laskuista jääneet muuttujat:

Remove["Global`*"]

Virtaa kuvaava toisen kertaluvun yhtälö:

yhtalo =  
      L i''[t] + R i'[t] + 
          1/ C i[
              t] == ω E0 Cos[ω t]

Vaimentamaton tapaus

Vaimentamattomassa tapauksessa piirissä ei ole vastusta ja yhtälö on

yhtalo1 =  yhtalo /. R -> 0

Alkuehtona olkoon, että piirissä ei tapahdu mitään:

alkuehto =  {i[0] == 0, i'[0] == 
          0}

Tämän ratkaisu on

rtk1 =  DSolve[{yhtalo1, alkuehto}, i[t], t]

Täsmällinen symbolinen tulos on tarpeen jatkon oivalluksia varten, joten sievennetään ratkaisu:

ratkaisu1 = i[t] /. First[rtk1] // FullSimplify

Ratkaisu muodostuu kahdesta kosinitermistä:  cos(t/(Sqrt[L C])) on peräisin homogeeniyhtälön yleisestä ratkaisusta ja cos(t ω) epähomogeeniyhtälön yksittäisratkaisusta. Edellinen kuvaa piirin sisäistä värähtelyä, jälkimmäinen ulkoisen jännitteen taajuudella tapahtuvaa värähtelyä.

Ratkaisu tässä muodossa ei kuitenkaan ole pätevä, jos nimittäjä tulee nollaksi:

restaajuus =  
      Solve[-1 + C L (ω^2) == 
          0, ω]

Nollaksi tuloa vastaavaa pakotteen taajuutta kutsutaan resonanssitaajuudeksi. Tällöin piirin sisäinen värähtelytaajuus ja pakotteen taajuus ovat samat. Kyseessä on tilanne, missä epähomogeenisen yhtälön yksittäisratkaisu saakin erilaisen muodon:

yhtalo2 =  yhtalo1 /. Last[restaajuus]

rtk2 =  DSolve[{yhtalo2, alkuehto}, i[t], t]

ratkaisu2 = i[t] /. First[rtk2] // FullSimplify

Tämä on tulkittavissa värähtelytermiksi, jossa virran amplitudi (Subscript[E, 0]) t / (2 L) kasvaa rajatta muuttujan t mukana. Käytännössä tämä johtaisi piirin palamiseen.

Arvoilla L = 0.1 H, C =  0.001 μF, (Subscript[E, 0]) = 230 V saadaan resonanssitaajuudella seuraava kuvio:

numratkaisu2 =  
      ratkaisu2 /. {L -> 0.1, C -> 0.001, 
          E0 -> 230}

Plot[numratkaisu2, {t, 0, 1.5}]

Resonanssitaajuus on

1/Sqrt[L C] /. {L -> 0.1, C -> 0.001}

Jos pakotteen taajuus on lähellä resonanssitaajuutta, saadaan erikoinen värähtely:

numratkaisu1 =  
      ratkaisu1 /. {L -> 0.1, C -> 0.001, 
          E0 -> 230, ω -> 90}

Plot[numratkaisu1, {t, 0, 1.5}]

Tässä pakote aluksi vahvistaa piirissä kulkevaa virtaa kuten resonanssitaajuuden tapauksessakin, mutta koska taajuudet eivät olekaan täsmälleen samat, värähtelyt siirtyvät vähitellen vastakkaisiin vaiheisiin, ja pakote alkaa sammuttaa piirin virtaa.

Syntynyt värähtely voidaan myös ymmärtää sinivärähtelyksi, jolla on sinimuotoinen vaihteleva amplitudi:

Cos[100 t]  -  
          Cos[90 t]  ==  - 2 Sin[5 t] Sin[95 t] // 
      Simplify

Vaimennettu tapaus

Yleisen vaimennetun tapauksen ratkaisu on

yhtalo

rtk =  DSolve[yhtalo, i[t], t]

ratkaisu =  i[t] /. First[rtk] // Simplify

Ratkaisu koostuu kahdesta termistä:

sisainen =  
      Select[ratkaisu, ! FreeQ[#, C[1]] &]  +  
        Select[ratkaisu, ! FreeQ[#, C[2]] &]

ulkoinen =  
      ratkaisu /. {C[1] -> 0, C[2] -> 0}

Sisäisen värähtelyn termi esittää vaimenevaa värähtelyä, sillä muuttujan t kerroin kummassakin eksponentissa on joko negatiivinen reaaliluku tai kompleksiluku, jonka reaaliosa on negatiivinen. Nämä termit siis kuolevat vähitellen pois.

Ulkoisen värähtelyn termi voidaan muokata seuraavasti. Pyritään saattamaan se muotoon, jossa on vain yksi sinifunktio kertoimena sopiva amplitudi A ja argumentissa sopiva vaihesiirto δ.

uusimuoto =  
      A Sin[ω t  +  δ] // TrigExpand

Vaatimalla että sini- ja kosinitermien kertoimet vanhassa ja uudessa esitysmuodossa ovat samat, saadaan ehdot, joista pyritään ratkaisemaan A ja δ.

ehdot =  
      MapThread[
        Equal, {Coefficient[
            ulkoinen, {Sin[ω t], Cos[ω t]}], 
          Coefficient[
            uusimuoto, {Sin[ω t], 
              Cos[ω t]}]}]

ratk =  Solve[ehdot, {A, δ}] // FullSimplify // 
          PowerExpand // FullSimplify

Pakotteen aiheuttama virta on siis sinimuotoinen amplitudina

amplitudi =  A /. Last[ratk]

Amplitudi riippuu pakotteen taajuudesta. Pyritään määrittämään maksimiamplitudi ja vastaava taajuus:

derivaatta =  D[amplitudi, ω] // Simplify

maksimikohta =  
      Solve[derivaatta == 0, ω]

maksimiamplitudi =  amplitudi /. Last[maksimikohta] // 
          Simplify // PowerExpand

Maksimiarvo saadaan siis resonanssitaajuudella.

Piirretään pakotteen (ulkoisen jännitteen) ja resonanssitaajuutta vastaavan virran kuvaajat:

numulkoinen =  
      ulkoinen /. {L -> 0.1, C -> 0.0001, R -> 5.0, 
          E0 -> 230}

jannite =  
      E0 Sin[ω t] /. E0 -> 230

res =  
      1/Sqrt[L C] /. {L -> 0.1, C -> 0.0001, R -> 5.0, 
          E0 -> 230}

Plot[
      Evaluate[{jannite, numulkoinen} /. ω -> res], {t, 
        0, 0.1}, 
      PlotStyle -> {RGBColor[0, 0, 0], 
          RGBColor[0, 1, 0]}]

Kuviossa on jännite mustalla ja virta vihreällä.

Vastaava kuvio, kun kyseessä ei ole resonanssitaajuus:

Plot[
      Evaluate[{jannite, numulkoinen} /. ω -> 280], {t, 
        0, 0.1}, 
      PlotStyle -> {RGBColor[0, 0, 0], 
          RGBColor[0, 1, 0]}]

Tehtäviä

Tutki, miten alkuehtojen muuttaminen vaikuttaa ratkaisuun vaimentamattomassa tapauksessa. Miten ratkaisun luonne muuttuu, kun ollaan resonanssikohdan lähellä?

Piirrä kuvaaja, joka esittää vaimennetun tapauksen virtaa pakotteen taajuuden funktiona. Onko vaimennetun piirin tapauksessa sellainen ratkaisu mahdollinen, jossa virran amplitudi rajatta kasvaa, ts. piiri palaa?

JP & SKK 08.05.2001