Simo K. Kivelä, 13.7.2004

Frégier'n lause

Toisen asteen käyrillä — ellipseillä, paraabeleilla, hyperbeleillä ja niiden erikoistapauksilla — on melkoinen määrä yksinkertaisia säännöllisyysominaisuuksia. Eräs tällainen on Frégier'n lause:

Olkoon P toisen asteen käyrällä sijaitseva piste ja olkoot PA ja PB kaksi tämän pisteen kautta kulkevaa toisiaan vastaan kohtisuoraa käyrän jännettä. Tällöin on olemassa kiinteä piste Q, jonka kautta suora AB kulkee riippumatta siitä, missä asennossa jänteet PA ja PB ovat. Piste Q sijaitsee pisteeseen P asetetulla käyrän normaalilla.

Kuva tilanteesta ellipsitapauksessa:

Lauseen erikoistapaus on ollut kevään 2001 ylioppilaskirjoitusten pitkän matematiikan kokeessa seuraavassa muodossa:

Suorakulmaisen kolmion kaikki kärjet sijaitsevat paraabelilla y = (x^2); suoran kulman kärki on paraabelin huipussa. Osoita, että jokaisen tällaisen kolmion hypotenuusa leikkaa paraabelin akselin samassa pisteessä. Määritä tämä piste.

Frégier´n lauseen todistus voi perustua analyyttiseen geometriaan. Tämän johdosta on luontevaa käyttää hyväksi jotakin symbolisen laskennan ohjelmaa, jolloin ei tarvitse huolehtia monimutkaisista sievennyksistä ja näissä herkästi syntyvistä virheistä. Ei symbolisten ohjelmienkaan käyttö ongelmatonta ole: niillä on omat heikkoutensa, joita on opittava varomaan.

Seuraavassa esitetään Frégier'n lauseen todistus ellipsitapauksessa Mathematica-nimistä symbolista ohjelmaa käyttäen, jolloin mekaaniset laskut voidaan antaa ohjelman tehtäviksi. Itse asiassa tämä kirjoitus on kokonaisuudesaan laadittu Mathematican avulla; se nimittäin sisältää myös ainakin jonkintasoiset mahdollisuudet tekstinkäsittelyyn ja matemaattisten kaavojen kirjoittamiseen.

Todistus

Tarkasteltavana oleva ellipsi voidaan sijoittaa origokeskiseksi, ilman että probeemaa mitenkään rajoitetaan. Muodostetaan siis origokeskisen ellipsin yhtälö ja talletetaan tämä nimelle ellipsi:

ellipsi= x^2/a^2 + y^2/b^2 == 1

Lauseessa esiintyvä piste P valitaan ellipsin kehältä. Jokainen kehäpiste voidaan esittää muodossa ( a cos(t), b sin(t) ). Tässä t on ns. parametri, joka voi saada arvot väliltä 0 ≤ t < 2 π; tällöin jokainen kehäpiste tulee huomioiduksi.

P={a Cos[t],b Sin[t]}

Pisteen koordinaatit voidaan sijoittaa ellipsin yhtälöön, jolloin se todellakin toteutuu:

ellipsi/.{x->P[[1]],y->P[[2]]}//Simplify

Pisteen P kautta asetetaan kaksi toisiaan vastaan kohtisuoraa suoraa. Annetaan näiden yhtälöt vektorimuodossa, jolloin niitä on näppärää käsitellä. Vektorit esitetään Mathematicassa kahden alkion listoina, esimerkiksi 2 (OverBar[i]) + 3 (OverBar[j]) muodossa {2,3}.  Koska suorat ovat kohtisuoria, tulee niiden suuntavektoreiden skalaaritulon olla = 0. Jos suuntavektorit kirjoitetaan muotoon {p,q} ja {-q,p} tämä ehto täyttyy, mutta muulla tavoin ei suorien suuntia ole rajoitettu. Vektoriesityksessä tarvittava parametri olkoon u:

PA= {x,y}==P+u {p,q}

PB={x,y}==P + u {-q,p}

Etsitään erikseen kummankin suoran ja ellipsin leikkauspisteet. Näitä on kummassakin tapauksessa kaksi ja niistä toinen on luonnollisesti ellipsillä oleva piste P, jonka kautta suorat asetettiin. Ratkaisujen sieventäminen edellyttää useampaa sievennyskäskyä peräkkäin aseteltuina: //FullSimplify//PowerExpand//FullSimplify :

ratk1= Solve[{ellipsi,PA},{x,y,u}]//FullSimplify//PowerExpand//FullSimplify

ratk2= Solve[{ellipsi,PB},{x,y,u}]//FullSimplify//PowerExpand//FullSimplify

Edelliset vaihtoehdot antavat etsityt pisteet Talletetaan saatujen toisten leikkauspisteiden A ja B koordinaatit omille nimilleen:

A= {x,y}/.ratk1[[1]]

B= {x,y}/.ratk2[[1]]

Suoran AB yhtälö voidaan esittää joko vektorimuodossa tai  x- ja y-koordinaatit sitovassa muodossa; seuraavassa jälkimmäinen vaihtoehto:

AB= y - A[[2]]== (B[[2]]-A[[2]])/(B[[1]]-A[[1]]) (x - A[[1]])

Lukija saattaa ihmetellä, miksi toisinaan suoralle käytetään vektorimuotoista, toisinaan xy-muotoista yhtälöä. Molemmat ovat periaatteessa yhtä hyviä. Edellä olevat valinnat on tehty tavoitteena mahdollisimman yksinkertaiset ja toisaalta symbolisen ohjelman käyttömahdollisuuksia mahdollisimman hyvin valaisevat laskut.

On ehkä aika piirtää tilanteesta kuvio. Kuviota varten tarvitaan jotkin numeeriset arvot:

lukuarvot= {a->3, b-> 2, t-> 1.2, p->2,q->3}

Lähtökohtana oleva piste P on tällöin

numP=P/.lukuarvot

Piirtämistä varten muodostetaan suorille PA ja PB xy-muotoiset yhtälöt eliminoimalla vektoriesityksestä parametri:

PAxy= Eliminate[PA,u]

PBxy= Eliminate[PB,u]

Tämän jälkeen voidaan piirtää itse kuva:

kuva1=ContourPlot[Evaluate[{ellipsi,PAxy,PBxy,AB}/. lukuarvot],{x,-5,5},{y,-5,5}]

Frégier'n lause väittää, että suora AB kulkee aina saman pisteen kautta riippumatta kohtisuorien suorien asennosta. Ehdokaspisteen löytämiseksi voidaan suorittaaa edellä oleva lasku siten, että suorien PA ja PB suunnat ovat erilaiset (mutta edelleen toisiaan vastaan kohtisuorat), jolloin saadaan jokin toinen suora AB. Ehdokaspiste on tällöin uuden ja vanhan suoran AB leikkauspiste.

Uudet suuntavektorit olkoot {r,s} ja {-s,r}.Uusi hypotenuusasuora saadaan hyvin yksinkertaisesti: korvataan aiemmassa suorassa AB vanhat suuntavektorin komponentit uusilla:

AB2= AB/.{p->r,q->s}

Tämän jälkeen voidaan ratkaista uuden ja vanhan suoran AB leikkauspiste. Tulos sievennetään.

ratk= Solve[{AB,AB2},{x,y}]

Q= {x,y}/.ratk[[1]]//Simplify

Tulos näyttää olevan riippumaton suuntavektoreiden komponenteista p, q, r ja s. Mutta tämä merkitsee, että Frégier´n lause on tullut todistetuksi: On löytynyt ehdokaspiste, joka ei riipu lähtökohtana olleista suuntavektoreista; se siis sijaitsee suoralla AB valittiinpa suuntavektorit miten tahansa!

Ratkaisu ei luonnollisestikaan mene edellä esitetyllä tavalla, jos p = r ja q = s. Tätä ei laskussa ole mitenkään suljettu pois. Mathematica kuitenkin käsittelee tällaisessa tilanteessa ns. geneeristä tapausta, ts. tapausta, missä mitään rajoittavia erikoisehtoja ei vallitse. Itse asiassa oletetaan siis p ≠ r, q ≠ s.

Lukija miettiköön, mistä seuraa, että löydetty piste on pisteen P kautta kulkevalla ellipsin normaalilla. Aivan lopussa oleva animaatio antanee ainakin viitteitä.

Esimerkkitapauksessa ehdokaspiste on

numQ=Q/.lukuarvot

Tilanteesta saadaan havainnollisempi kuva piirtämällä kaksi keskenään kohtisuoraa suoraparia, näitä vastaavat suorat AB ja leikkauspiste:

lukuarvot2= {a->3, b-> 2, t-> 1.2, p->3,q->1}

kuva2= ContourPlot[Evaluate[{ellipsi,PAxy,PBxy,AB}/.lukuarvot2],{x,-5,5},{y,-5,5}];
Show[kuva1,kuva2,Graphics[{PointSize[0.03],Point[numP],Point[numQ]}]]

Animaatio

Tilannetta voidaan havainnollistaa myös animaatiolla:

Siirrä liukusäädintä!

Manipulate[Show[Graphics[{ContourPlot[Evaluate[{ellipsi,PAxy,PBxy,AB}/. {a->3,b->2,t->1.2,p->Cos[w],q->Sin[w]}],{x,-5,5},{y,-5,5}][[1]],{PointSize[0.03`],Point[numP],Point[numQ]}},PlotRange->{{-5,5},{-5,5}}],AspectRatio->1],{w,0,Pi,0.01},SaveDefinitions->True]

Harjoitustehtäviä

1) Osoita, että piste Q sijaitsee pisteeseen P asetetulla ellipsin normaalilla.

2) Pisteen Q sijainti riippuu pisteen P sijainnista ellipsillä. Tutki, millaisen käyrän piste Q piirtää, kun piste P kiertää koko ellipsin.

3) Todista Frégier'n lause paraabelitapauksessa.